flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; };

        # From 22-04-2026
        stdpp = with pkgs; coqPackages.lib.overrideCoqDerivation {
          version = "dev";
          release."dev".sha256 = "hN+sEZcIaFoFF2+4dStTc0TRz5A03US6csEk5q0r/z8=";
          release."dev".rev = "d3c67aa46ed22b1e593457cd34fc711f1a53b8be";
        } coqPackages.stdpp;

        # From 04-05-2026
        iris = with pkgs; coqPackages.lib.overrideCoqDerivation {
          version = "dev";
          release."dev".sha256 = "P2cELkPl8RcHE1PzoswhMjXS5l8RBInW9q7Es0wtkus=";
          release."dev".rev = "306c37bfc12b0d459d302dabad9de5ab09d6a6d4";
          propagatedBuildInputs = [ stdpp ];
        } coqPackages.iris;

        # From 11-03-2026
        iris-named-props = with pkgs; coqPackages.mkCoqDerivation rec {
          pname = "iris-named-props";
          owner = "tchajed";
          version = "dev";
          release."dev".sha256 = "1YHAItQ9XsCy+0M/pG2ib/GeaLTFJOrGJwF8noViwKg=";
          release."dev".rev = "ca663d2709888a789a03edc861b7bde86ddd56e5";
          propagatedBuildInputs = [ iris ];
        };
      in
      {
        devShells.default = with pkgs; mkShell {
          buildInputs = [ coq iris iris-named-props ];
        };

        formatter = pkgs.nixpkgs-fmt;
      });
}